* * * *
14 Visitatori, 0 Utenti

Il Nintendo DS dispone di una limitata quantità di memoria che il programmatore deve impiegare sapientemente tra codice e dati. I problemi cominciano a sorgere quando si impiegano massicciamente grafica e suoni, con il rischio di occupare in breve tempo tutte le risorse disponibili. In questo caso occorrerebbe caricare dinamicamente i dati in memoria, man mano che ce ne fosse necessità.

Un altro scenario tipico è la gestione dei salvataggi: ancora non sappiamo come salvare i progressi o le impostazioni di un nostro ipotetico gioco, per poi ricaricarli ad un successivo riavvio della macchina.

E come gestire i livelli? Sarebbe utile poterli caricare in memoria, in modo da non dover ricompilare il codice ad ogni modifica dei livelli di gioco.

La soluzione ai suddetti problemi è l'impiego del filesystem. Il devkitARM permette di gestirne due tipi differenti: NitroFS e FAT. Il filesystem NitroFS è utilizzabile solo in lettura (le operazioni in scrittura vengono semplicemente ignorate) e ripropone le stesse modalità di immagazzinamento dei files utilizzato nel devkit ufficiale Nintendo: i files vengono accodati all'eseguibile grazie ad un programma, ndstool.exe, che genera un eseguibile monolitico partendo dall'eseguibile originario e aggiungendo i files da inserire nel filesystem. Il filesystem FAT è invece utilizzabile sia in lettura che in scrittura e sfrutta un ingegnoso sistema di driver per adattarsi a qualsiasi flashcard in commercio.
Gli emulatori supportano perfettamente il filesystem NitroFS, ma hanno qualche problema con il FAT: il no$gba, ad esempio, non lo supporta; il DeSmuME invece fornisce un supporto limitato alla sola lettura, dato che tutte le modifiche sui files effettuate in scrittura andranno perse alla chiusura dell'emulatore. Altra limitazione riguarda la creazione di nuovi files, che non risulta possibile.

Prima di rilasciare i vostri programmi con supporto FAT, suggerisco di testarli su un vero Nintendo DS per non avere brutte sorprese.

L'accesso ai files può avvenire sia sfruttando il binding delle funzioni standard del c (fopen, fread, fwrite, fclose, fseek), sia le funzioni proprie del Pascal (assign, reset, rewrite, read, write, close, seek). Vedremo ppiù avanti nell'articolo due esempi di utilizzo del filesystem NitroFS e del filesystem FAT, utilizzando le funzioni I/O standard del Pascal, che sono poi quelle che ci interessano direttamente.


Interfaccia DLDI

Parlavamo prima del sistema di driver utilizzato per l'accesso al filesystem FAT sulle diverse flashcard: esso viene chiamato DLDI (Dynamically Linked Device Interface) e consta di una serie di driver, uno per ogni periferica di backup (o flashcard) esistente sul mercato, e di un tool a linea di comando utilizzato per "patchare" l'eseguibile .nds con il driver specifico. Niente di troppo complicato, comunque. Vi basti sapere che, per patchare il file .nds, è sufficiente utilizzare la seguente linea di comando:

dlditool.exe your_driver.dldi your_file.nds

dove your_file.nds è l'eseguibile .nds da patchare e your_driver.dldi è il driver dldi da utilizzare. Ovviamente i file .nds e .dldi devono essere nello stesso percorso.

Per maggiori informazioni: http://dldi.drunkencoders.com/


Impostazioni del DeSmuME

Come dicevamo poc'anzi, l'unico emulatore che dispone di un supporto decente dei filesystem è il DeSmuME; procuratevi quindi l'ultima versione dal sito ufficiale. L'emulatore andrà configurato in maniera differente, a seconda di quale filesystem si intende utilizzare.

Per utilizzare il filesystem FAT, nel menu dell'emulatore occorre andare su "Emulation->Slot1"; nella finestra che si aprirà bisognerà impostare "R4" per emulare la card R4, quindi selezionare la directory dove sono presenti i files del filesystem. Infine occorre premere il tasto "Ok" per confermare la configurazione. Ovviamente l'eseguibile nds andrà patchato con la dldi per R4. Da ricordare anche che quando si testa un nuovo eseguibile nds situato in una directory differente, occorre cambiare la configurazione dell'emulatore di conseguenza. Parlo per esperienza personale, visto che una volta ho perso due giorni dietro a un filesystem che non voleva funzionare, salvo accorgermi poi che non avevo specificato il corretto path nell'emulatore...

Per l'utilizzo con NitroFS bisogna invece impostare "Retail" nella stessa finestra vista appena sopra. Non occorre configurare altro, perché in NitroFS il filesystem è "appeso" all'eseguibile nds.

Possiamo finalmente vedere alcuni esempi di utilizzo dei due filesystem.


Filesystem in lettura/scrittura (FAT)

Nelle prossime righe di codice vedremo un esempio sull'utilizzo dei files tipizzati con il filesystem di tipo FAT. Simuleremo la lettura/scrittura di un high score su file: leggeremo i dati, li mostreremo a schermo, li modificheremo salvandoli sul file, li ricaricheremo e mostreremo sullo schermo il risultato delle modifiche.

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
program fat_r_w;

{$mode objfpc}

uses
  ctypes, nds9, fat;

type
  TMyScore = packed record
    name: array [0..6] of char;
    score: longint;
  end;
  TMyScoreFile = file of TMyScore;
  PMyScoreFile = ^TMyScoreFile;

function WriteDAT(var aFile: TMyScoreFile; var aPlayer: TMyScore): boolean;
begin
  result := true;
  try
    try
      Assign(aFile, '/scores.dat');
      Rewrite(aFile);
      Write(aFile, aPlayer);
    except
      result := false;
    end;
  finally
    Close(aFile);
  end;
end;

function ReadDAT(var aFile: TMyScoreFile; var aPlayer: TMyScore): boolean;
begin
  result := true;
  try
    try
      Assign(aFile, '/scores.dat');
      Reset(aFile);
      Read(aFile, aPlayer);
    except
      result := false;
    end;
  finally
    Close(aFile);
  end;
end;

var
  f: TMyScoreFile;
  Player: TMyScore;
  sc: TMyScore;
  
begin
  defaultExceptionHandler();
  consoleDemoInit();
  
  iprintf(#10#9 + 'FAT read/write example' + #10); 
  iprintf(   #9 + '----------------------' + #10); 

  if (fatInitDefault()) then
  begin
    printf(#10'Loading from scores.dat...'#10);
    if ReadDAT(f, Player) then
    begin
      printf('Done.'#10#10);
      iprintf('Name:  %s'#10, Player.name);
      iprintf('Score: %i'#10, Player.score);
    end else
      printf('Error reading from scores.dat!'#10#10);
    
    printf(#10'Writing on scores.dat...'#10);
    sc.Name := 'John'#0;
    sc.Score := 200;
    if WriteDAT(f, sc) then
      printf('Done.'#10#10)
    else
      printf('Error writing on scores.dat!'#10#10);

    printf(#10'Reloading from scores.dat...'#10);
    if ReadDAT(f, Player) then
    begin
      printf('Done.'#10#10);
      iprintf('Name:  %s'#10, Player.name);
      iprintf('Score: %i'#10, Player.score);
    end else
      printf('Error reading from scores.dat!'#10#10);
       
  end else
    iprintf('fatInit failure: terminating'#10);
  
  while true do
    swiWaitForVBlank();
end.

[6] Aggiungiamo la libreria "fat"

[9-14] Definiamo il record che conterrà il... record! 

[16-30] e [32-46] Definiamo le due funzioni che si occuperanno di leggere e scrivere il file tipizzato.

[49-51] Dichiariamo le variabili che serviranno nel programma

[54] La procedura defaultExceptionHandler() si occupa di attivare la gestione delle eccezioni. In caso di errore grave nel programma, verrà mostrata una schermata rossa con alcune utili informazioni sull'errore, un po' come la schermata blu di Windows (e qui gli amighisti si incavoleranno, perché la schermata rossa in effetti riprende il "Guru Meditation Error" dell'Amiga!)

[55] Attiviamo la console di default per mostrare il testo a schermo

[60] Inizializziamo la libreria FAT tramite la funzione fatInitDefault(), che restituisce false in caso di errore.

[63-69] Effettuiamo la letture del file scores.dat e stampiamone a schermo il contenuto

[71-77] Modifichiamo i valori nel file scores.dat

[79-86] Ricarichiamo i dati da scores.dat e stampiamoli a schermo, per constatare come siano effettivamente cambiati

w92OL


Filesystem in sola lettura (NitroFS)

E' ora la volta del filesystem di tipo NitroFS. Questa volta caricheremo i dati da un normale file di testo e lo stamperemo a schermo, utilizzando però le funzioni proprie del pascal anziché printf e similari.

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
program nitro_r_w;

{$mode objfpc}

uses
  ctypes, nds9, filesystem;

var
  SomeTxtFile: TextFile;
  buffer: string;
   
begin
  defaultExceptionHandler();
  consoleDemoInit();

  writeln('');
  writeln(#9#9 + 'NitroFS read example');
  writeln(#9#9 + '--------------------');
  writeln('');

  if (nitroFSInit()) then
  begin
   Assign(SomeTxtFile, '/textfile.txt') ;
   Reset(SomeTxtFile) ;
   while not EOF(SomeTxtFile) do
   begin
    ReadLn(SomeTxtFile, buffer) ;
    writeLn(buffer);
   end;
   Close(SomeTxtFile);
  end else
    writeln('nitroFSInit failure: terminating');
  
  flush(output);
  while true do
    swiWaitForVBlank();
end.

[6] Utilizziamo la unit filesystem

[9-10] Alcune variabili che utilizzeremo nel programma

[21] Inizializziamo la libreria NitroFS tramite la funzione nitroFSInit(), che restituisce false in caso di errore.

[23-30] Apriamo il file di testo, leggiamone il contenuto, stampiamolo a schermo e richiudiamo il file

[34] La chiamata a flush(output) è necessaria per inviare allo schermo il buffer appena modificato, altrimenti avremmo uno schermo nero!

unVO5


Conclusioni

Quando utilizzare NitroFS e FAT? Un utilizzo "sapiente" potrebbe essere quello di sfruttare NitroFS per tutte quelle operazioni che richiedono l'accesso in sola lettura (caricamento di immagini, livelli di gioco, ecc.), limitando l'utilizzo di FAT alla gestione dei salvataggi di stato del gioco e dei punteggi. 

Per ora è tutto! Nelle prossime lezioni cominceremo a sporcarci le mani con la grafica del Nintendo DS, quindi state sintonizzati!


Scarica i sorgenti


Per commenti e chiarimenti: http://www.lazaruspascal.it/index.php?topic=78.0


Share on Twitter! Digg this story! Del.icio.us Share on Facebook! Technorati Reddit StumbleUpon

Articles in « Free Pascal per DS »

Recenti

How To

Trascinare un file nel programma da xinyiman
DB concetti fondamentali e ZeosLib da xinyiman
Recuperare codice HTML da pagina web da xinyiman
Mandare mail con Lazarus da xinyiman
Stabilire il sistema operativo da xinyiman
Esempio lista in pascal da xinyiman
File INI da xinyiman
Codice di attivazione da xinyiman
Realizzare programmi multilingua da xinyiman
Lavorare con le directory da xinyiman
Utilizzare Unità esterne da Loryea
TTreeView da xinyiman
TTreeview e Menu da xinyiman
Generare controlli RUN-TIME da xinyiman
LazReport, PDF ed immagini da xinyiman
Intercettare tasti premuti da xinyiman
Ampliare Lazarus da xinyiman
Lazarus e la crittografia da xinyiman
System Tray con Lazarus da xinyiman
UIB: Unified Interbase da Microges2000
Il file: questo sconosciuto da Microges2000
Conferma di chiusura di un applicazione da xinyiman
Liste e puntatori da Microges2000
Overload di funzioni da Microges2000
Funzioni a parametri variabili da Microges2000
Proprietà da Microges2000
Conversione numerica da Microges2000
TImage su Form e Panel da Maverich
Indy gestiore server FTP lato Client da Maverich
PopUpMenu sotto Pulsante (TSpeedButton) da Maverich
Direttiva $macro da Microges2000
Toolbar da xinyiman
Evidenziare voci TreeView da Maverich
Visualizzare un file Html esterno da Maverich
StatusBar - aggirare l'errore variabile duplicata da Maverich
Da DataSource a Excel da xinyiman
Le permutazioni da xinyiman
Brute force da xinyiman
Indy 10 - Invio email con allegati da Maverich
La gestione degli errori in Lazarus da xinyiman
Pascal Script da xinyiman
Linux + Zeos + Firebird da xinyiman
Dataset virtuale da xinyiman
Overload di operatori da Microges2000
Lavorare con file in formato JSON con Lazarus da nomorelogic
Zeos ... dietro le quinte (prima parte) da Stilgar
Disporre le finestre in un blocco unico (come Delphi) da Maverich
Aspetto retrò (Cmd Line) da xinyiman
Come interfacciare periferica twain da Narciso
Ubuntu - aggiornare free pascal e lazarus da xinyiman
fpcup: installazioni parallele di lazarus e fpc da nomorelogic
Free Pascal e Lazarus sul Raspberry Pi da nomorelogic
Cifratura: breve guida all'uso dell'algoritmo BlowFish con lazarus e free pascal. da nomorelogic
Creare un server multithread da xinyiman
guida all'installazione di fpc trunk da subversion in linux gentoo da nomorelogic
Indice da nomorelogic
DB concetti fondamentali e connessioni standard da xinyiman
Advanced Record Syntax da nomorelogic
DB concetti fondamentali e DBGrid da xinyiman
DB concetti fondamentali e TDBEdit, TDBMemo e TDBText da xinyiman
Advanced Record Syntax: un esempio pratico da nomorelogic
Superclasse form base per programmi gestionali (e non) da nomorelogic
Superclasse form base per programmi gestionali (e non) #2 - log, exception call stack, application toolbox da nomorelogic
Superclasse form base per programmi gestionali (e non) #3 - traduzione delle form da nomorelogic
Superclasse form base per programmi gestionali (e non) #4 - wait animation da nomorelogic
Un dialog per la connessione al database:TfmSimpleDbConnectionDialog da nomorelogic
Installare lazarus su mac osx sierra da xinyiman
Utenti
Stats
  • Post in totale: 10336
  • Topic in totale: 1311
  • Online Today: 12
  • Online Ever: 74
  • (Luglio 09, 2012, 11:05:53 am)
Utenti Online
Users: 0
Guests: 14
Total: 14

Disclaimer:

Questo blog non rappresenta una testata giornalistica poiché viene aggiornato senza alcuna periodicità. Non può pertanto considerarsi un prodotto editoriale ai sensi della legge n. 62/2001.