Italian community of Lazarus and Free Pascal

Portal features

Pagine: 1 [2] 3 4 ... 14

04 Set 2014 - Superclasse form base per programmi gestionali (e non) #4 - wait animation

Written by nomorelogic Settembre 04, 2014, 03:29:00 pm 13853 Views Rating: 0 (0 Rates) Print

In questo articolo andremo ad implementare una wait animation. Si tratta di una semplice animazione grafica che girerà su un thread separato rispetto a quello principale dell'applicazione.

Read More

29 Ago 2014 - Superclasse form base per programmi gestionali (e non) #3 - traduzione delle form

Written by nomorelogic Agosto 29, 2014, 06:51:00 pm 12506 Views Rating: 0 (0 Rates) Print

In questo articolo vedremo come implementare un sistema di traduzione dell'applicazione tramite resourcestring.

Read More

28 Ago 2014 - Superclasse form base per programmi gestionali (e non) #2 - log, exception call stack, application toolbox

Written by nomorelogic Agosto 28, 2014, 07:27:00 pm 13553 Views Rating: 0 (0 Rates) Print

Read More

24 Ago 2014 - Superclasse form base per programmi gestionali (e non)

Written by nomorelogic Agosto 24, 2014, 10:16:00 am 13597 Views Rating: 0 (0 Rates) Print

Quando si sviluppa una applicazione destinata ad avere un certo numero di form, è bene prevedere che tutte abbiamo lo stesso
comportamento. Se poi a lavorare sullo stesso progetto c'è più di uno sviluppatore allora un metodo comune di lavoro diventa
obbligatorio.
Solitamente si dice che si devono definire degli standard di sviluppo.

Read More

20 Lug 2014 - Advanced Record Syntax: un esempio pratico

Written by nomorelogic Luglio 20, 2014, 12:13:00 am 13698 Views Rating: 0 (0 Rates) Print

In un'altro articolo (http://www.lazaruspascal.it/index.php?page=145) avevamo visto un po' di teoria relativamente a Advanced Record Syntax, ora proveremo un esempio pratico.

Quello che segue è il sorgente completo di un programmino da console che serve a fare un paio di test di questa caratteristica. Dopo il codice alcuni commenti.

Codice: [Seleziona]


program project1;

{$mode delphi}{$H+}
{$DEFINE USE_ADVANCED_RECORD_SYNTAX}

uses Classes;

type

  { TCliente }

  TCliente = record
  public
     type
       TIndirizzo = record
         Indirizzo: string[40];
         CAP: string[5];
         Citta: string[40];
         Prov: string[2];
       end;
       TTipoIndirizzo = (tiSedeOp, tiSedeLeg, tiSedeCon);
     var
       ID: integer;
       RagSociale: string[40];
       ParIva: string[13];

       SedeOperativa: TIndirizzo;
       SedeLegale: TIndirizzo;
       SedeConsegna: TIndirizzo;

     {$IFDEF USE_ADVANCED_RECORD_SYNTAX}
     procedure WriteIndirizzo(tipo: TTipoIndirizzo = tiSedeOp);
     {$ENDIF}
  end;

var Cliente: TCliente;

{ TCliente }

{$IFDEF USE_ADVANCED_RECORD_SYNTAX}
procedure TCliente.WriteIndirizzo(tipo: TTipoIndirizzo);
begin
   WriteLn(RagSociale);

   // test output
   case tipo of
      tiSedeLeg: if (SedeLegale.Indirizzo = '') and
                    (SedeLegale.CAP = '') and
                    (SedeLegale.Citta = '') and
                    (SedeLegale.Prov = '') then
                    tipo := tiSedeOp;
      tiSedeCon: if (SedeConsegna.Indirizzo = '') and
                    (SedeConsegna.CAP = '') and
                    (SedeConsegna.Citta = '') and
                    (SedeConsegna.Prov = '') then
                    tipo := tiSedeOp;
   end;

   // output
   case tipo of
      tiSedeOp: begin
                  Writeln(SedeOperativa.Indirizzo);
                  Writeln(SedeOperativa.CAP, ' - ' , SedeOperativa.Citta, ' (', SedeOperativa.Prov, ')');
      end;
      tiSedeLeg: begin
                  Writeln(SedeLegale.Indirizzo);
                  Writeln(SedeLegale.CAP, ' - ', SedeLegale.Citta, ' (', SedeLegale.Prov, ')');
      end;
      tiSedeCon:begin
                  Writeln(SedeConsegna.Indirizzo);
                  Writeln(SedeConsegna.CAP, ' - ', SedeConsegna.Citta, ' (', SedeConsegna.Prov, ')');
      end;
   end;
end;
{$ENDIF}


begin

  WriteLn('Test Advanced Record Syntax');
  Write('Advanced Record Syntax: ');
  {$IFDEF USE_ADVANCED_RECORD_SYNTAX}
  WriteLn('ON');
  {$ELSE}
  WriteLn('OFF');
  {$ENDIF}

  WriteLn('Size TCliente: ', SizeOf(Cliente));

  with Cliente do begin
     ID:= 1;
     RagSociale:='Lazarus Enterprises Inc.';
     ParIva := 'IT01234567890';

     With SedeOperativa do begin
        Indirizzo := 'Via dei mille nr. 999';
        CAP := '12345';
        Citta := 'Firenze';
        Prov := 'FI';
     end;

     With SedeConsegna do begin
        Indirizzo := 'Via dei bancali nr. 541';
        CAP := '55442';
        Citta := 'Ancona';
        Prov := 'AN';
     end;


  end;


  {$IFDEF USE_ADVANCED_RECORD_SYNTAX}
  Cliente.WriteIndirizzo(tiSedeLeg);
  {$ELSE}
  WriteLn(Cliente.RagSociale);
  Writeln(Cliente.SedeLegale.Indirizzo);
  Writeln(Cliente.SedeLegale.CAP, ' - ', Cliente.SedeLegale.Citta, ' (', Cliente.SedeLegale.Prov, ')');
  {$ENDIF}


end.

Le direttive
Sicuramente bisogna prestare attenzione alle direttive di questo sorgente.
La prima è da considerarsi obbligatoria in quanto questa caratteristica, almeno per ora, è stata implementata per compatibilità verso delphi e quindi bisogna impostare questo tipo di sintassi:

Codice: [Seleziona]

{$mode delphi}

La direttiva seguente:

Codice: [Seleziona]

{$DEFINE USE_ADVANCED_RECORD_SYNTAX}

Non è assolutamente obbligatoria, l'ho introdotta per meglio far comprendere alcuni aspetti di questa sintassi. Iniziamo quindi lasciando così questa direttiva.

Il record
Ho definito un tipo record per la gestione di una ipotetica tabella dei clienti. La dichiarazione inizia con:

Codice: [Seleziona]

TCliente = record

Notare che al suo interno ho nidificato un'altro tipo record:

Codice: [Seleziona]

TIndirizzo = record

in quanto più sotto ho bisogno di 3 campi dello stesso tipo (SedeOperativa, SedeLegale e SedeConsegna).
Notare soprattutto che se è attiva la direttiva USE_ADVANCED_RECORD_SYNTAX allora la procedura WriteIndirizzo farà parte del record, esattamente come ci aspetteremmo per una classe.

La procedura WriteIndirizzo
Più sotto trovate il codice della procedura che non fa altro che, appunto, scrivere sulla console l'indirizzo richiesto. Si aspetta infatti un parametro (tipo indirizzo) però è fatta in modo che: se l'indirizzo è "sede legale" o "sede consegna" e se questo indirizzo non è mai stato fornito, allora viene scritto come default l'indirizzo "sede operativa". Ovviamente, nell'ipotetica applicazione, questo indirizzo è obbligatoriamente presente.

Eseguiamo con direttiva USE_ADVANCED_RECORD_SYNTAX
Se apriamo una console e lanciamo il programma, otteniamo il seguente output:

Codice: [Seleziona]

Test Advanced Record Syntax
Advanced Record Syntax: ON
Size TCliente: 332
Lazarus Enterprises Inc.
Via dei mille nr. 999
12345 - Firenze (FI)

Notare che l'indirizzo richiesto è la "sede legale" (Cliente.WriteIndirizzo(tiSedeLeg)) che non è mai stata fornita e a video troviamo la "sede operativa".
Notare anche la dimensione del record: 332 byte.

Eseguiamo senza direttiva USE_ADVANCED_RECORD_SYNTAX
Disabilitiamo ora la direttiva commentandola in questo modo:

Codice: [Seleziona]

// {$DEFINE USE_ADVANCED_RECORD_SYNTAX}

e poi ricompiliamo il programma e lanciamolo nuovamente.
Otterremo il seguente output:

Codice: [Seleziona]

Test Advanced Record Syntax
Advanced Record Syntax: OFF
Size TCliente: 332
Lazarus Enterprises Inc.

 -  ()

Nel codice tradizionale si fa espressamente riferimento alla "sede legale" e non viene stampato nulla. Ovviamente avremmo potuto ovviare mettendo del codice "a mano", in modo tradizionale, all'interno del programma ed avremmo ottenuto lo stesso risultato. In questo modo però avremmo dovuto rinunciare all'incapsulazione ed a tutti i vantaggi che ne derivano.
Notare la dimensione del record, anche in questo caso: 332 byte. Esattamente come nell'altro caso.

Pagine: 1 [2] 3 4 ... 14

Italian community of Lazarus and Free Pascal

News:

04 Set 2014 - Superclasse form base per programmi gestionali (e non) #4 - wait animation

29 Ago 2014 - Superclasse form base per programmi gestionali (e non) #3 - traduzione delle form

28 Ago 2014 - Superclasse form base per programmi gestionali (e non) #2 - log, exception call stack, application toolbox

24 Ago 2014 - Superclasse form base per programmi gestionali (e non)

20 Lug 2014 - Advanced Record Syntax: un esempio pratico