Italian community of Lazarus and Free Pascal

Programmazione => Componenti Aggiuntivi => Topic aperto da: SB - Marzo 17, 2019, 11:49:01 am

Titolo: fcl-pdf
Inserito da: SB - Marzo 17, 2019, 11:49:01 am
Qualcuno conosce fcl-pdf?
Di documentazione non ne trovo e l'esempio incluso non mi funziona (su Linux). Sembra che non riesca a trovare i font.
C'è qualche altra libreria per produrre pdf? Mi servirebbe qualcosa di non visuale.

Grazie
Titolo: Re:fcl-pdf
Inserito da: bonmario - Marzo 17, 2019, 12:53:29 pm
Conosco, per sentito dire, PowerPdf, ma non l'ho mai usato.

Ciao, Mario
Titolo: Re:fcl-pdf
Inserito da: SB - Marzo 17, 2019, 04:27:37 pm
Farò qualche prova, grazie.
Titolo: Re:fcl-pdf
Inserito da: antoniog - Marzo 18, 2019, 09:09:22 am
prova a vedere in .../components/printers/samples/dialogs/selectprinter.lpici sono vari esempi e il pulsante "Execute TPrintDiagolog" apre il dialogo dove puoi scegliere se stampare su file
Titolo: Re:fcl-pdf
Inserito da: SB - Marzo 18, 2019, 06:05:39 pm
Provvisoriamente sto usando questa tecnica con cups come stampante virtuale che produce un pdf. Però è qualcosa che deve essere installato nel pc.
Se possibile vorrei qualcosa di autonomo.
Titolo: Re:fcl-pdf
Inserito da: xinyiman - Marzo 19, 2019, 08:28:27 am
Questo lo hai provato?

http://www.lazaruspascal.it/index.php?page=47

Richiede comunque l'installazione del package powerpdf in lazarus.
Titolo: Re:fcl-pdf
Inserito da: Mimmo - Marzo 19, 2019, 10:28:58 am
Ciao,
sotto linux non l'ho usata, su windows il font deve essere disponibile come file ttf e deve essere precaricato nel documento prima di essere utilizzato. Qualcosa del genere:

Codice: [Seleziona]
var
  fontTitle : integer;
[...]
doc := TPDFDocument.Create(Nil);
[...]
fontTitle := doc.AddFont(IncludeTrailingPathDelimiter(...) + 'VeraMono-Bold.ttf', 'VeraMono-Bold');
[...]
page := doc.Pages.AddPage;
page.PaperType:= ptA4;
page.UnitOfMeasure:= uomPixels;
[...]
page.SetFont(fontTitle, 12);
page.SetColor(clBlack, false);
page.WriteText(x, y, 'bla bla bla');
[...]

Penso che la cosa sia valida anche per Linux.
Titolo: Re:fcl-pdf
Inserito da: Mimmo - Marzo 19, 2019, 03:34:59 pm
Aggiungo una cosa: se hai qualche domanda specifica chiedi pure, io l'ho usata abbastanza quella libreria e più o meno ne sono sempre venuto a capo.
Ho provato anche powerpdf, che però mi pare abbia uno sviluppo un po' più rallentato, e SynPdf che ha delle cose molto buone, tipo la possibilità di generare i PDF/A, ma funziona (o funzionava) solo sotto windows e il porting su linux era praticamente impossibile.
Titolo: Re:fcl-pdf
Inserito da: SB - Marzo 19, 2019, 05:09:17 pm
Grazie a tutti. Appena posso faccio delle prove.
Titolo: Re:fcl-pdf
Inserito da: SB - Marzo 21, 2019, 02:34:05 pm
il font deve essere disponibile come file ttf e deve essere precaricato nel documento prima di essere utilizzato. Qualcosa del genere:

Codice: [Seleziona]
fontTitle := doc.AddFont(IncludeTrailingPathDelimiter(...) + 'VeraMono-Bold.ttf', 'VeraMono-Bold');
Penso che la cosa sia valida anche per Linux.

Grazie! Funziona anche su Linux.  ;D
Adesso ci gioco un po'
Titolo: Re:fcl-pdf
Inserito da: SB - Marzo 21, 2019, 06:49:22 pm
Aggiungo una cosa: se hai qualche domanda specifica chiedi pure, io l'ho usata abbastanza quella libreria e più o meno ne sono sempre venuto a capo.

Mimmo, sai se esiste della documentazione sulla fcl-pdf? O devo capire come funziona dal sorgente dell'esempio?

Per xinyiman: google ha già indicizzato questi post. Cercando "lazarus fcl-pdf" il forum compare al quinto posto!  ;D
Titolo: Re:fcl-pdf
Inserito da: Mimmo - Marzo 25, 2019, 11:24:47 am
Purtroppo documentazione non ne ho trovata, io sono andato per tentativi spulciandomi gli esempi.
La cosa veramente menosa è adattare il layout alle dimensioni del foglio e alla quantità di dati che devi inserire nel pdf.
Per il resto è tutta una sequenza di "cambia font", "scrivi qualcosa", "cambia colore", "disegna una linea o un rettangolo", "controlla di non aver finito lo spazio", ecc...
In generale cosa dovresti fare? Rappresentare dei dati tabellari? Inserire bitmap?
Io per lo più ho ricreato moduli che assomigliano a delle griglie un po' più articolate. Se questo è il tuo caso e può esserti d'aiuto posso postare un piccolo esempio della tecnica che ho utilizzato.
Titolo: Re:fcl-pdf
Inserito da: Mimmo - Marzo 25, 2019, 11:41:08 am
Questo ad esempio è per creare una sorta di griglia, con un footer ed un messaggio di riepilogo al fondo. E' il "riassunto" fatto rapidamente di una procedura più ampia, non ho testato l'output, potrebbero esserci dei bachetti nei conti, prendila come spunto...  ;)

Codice: [Seleziona]
procedure Sample (const aFileName: string);
var
  doc : TPDFDocument;
  sec : TPDFSection;
  page : TPDFPage;
  fs : TFileStream;
  fontText : integer;
  pageWidth, pageHeight: integer;
  x, y : double;
  horizBorder, vertBorder: integer;
  currentPage, i, split, rowHeight: integer;
  tableCols : array [1..4] of integer;
  tableCoords : array [1..5] of integer;
  tmp: String;

  function EstimatePos (aBorderDx : integer; aText : string) : double;
  begin
    Result := aBorderDx - 2 - (Length(aText) * 4.77);
  end;


  procedure WriteFooter (const aFineDoc : boolean);
  var
    tString : String;
  begin
    page.SetColor(clDkGray, false);
    page.SetFont(fontText, 10);
    tString := 'PAGE ' + IntToStr(currentPage);
    page.WriteText(x, 20, tString);
    page.SetColor(clBlack, false);
  end;


  procedure AddPageIfNecessary();
  begin
    if (currentPage = 0) or (y <= vertBorder) then
    begin
      if currentPage > 0 then
        WriteFooter(false);

      inc (currentPage);
      page := doc.Pages.AddPage;
      page.PaperType:= ptA4;
      page.UnitOfMeasure:= uomPixels;
      page.Orientation:= ppoPortrait;
      pageWidth := round(page.Paper.Printable.R - page.Paper.Printable.L);
      pageHeight := round(page.Paper.Printable.B - page.Paper.Printable.T);
      sec.AddPage(page);
      x := horizBorder;
      y := pageHeight - vertBorder;
      // write a copyright notice on the right side of the page
      page.SetFont(fontText, 5);
      page.WriteText(pageWidth, y, '42 L.t.d. ' + UTF8Encode('©') + ' www.42.com', 270);
    end;
  end;

begin
  doc := TPDFDocument.Create(Nil);
  try
    doc.Infos.Title:= 'My memories';
    doc.Infos.Author:= 'Zaphod Beeblebrox';
    doc.Infos.Producer:= 'Sample application';
    doc.Infos.CreationDate:= Now;
    // with poPageOriginAtTop: coords are calculated from the top of the page
    doc.Options:= [poCompressFonts, poCompressText, poCompressImages];
    doc.StartDocument;
    sec:= doc.Sections.AddSection;

    fontText:= doc.AddFont('c:\temp\Times.ttf', 'Times');

    rowHeight:= 12;
    horizBorder:= 30;
    vertBorder:= 30;

    AddPageIfNecessary;

    split := (pageWidth div 6);
    tableCols[1] := (split);
    tableCols[2] := (split * 2); // doubled size
    tableCols[3] := (split * 2); // doubled size
    tableCols[4] := (split);

    tableCoords[1] := trunc(x);
    tableCoords[2] := tableCols[1] + TableCoords[1];
    tableCoords[3] := tableCols[2] + TableCoords[2];
    tableCoords[4] := tableCols[3] + TableCoords[3];
    tableCoords[5] := tableCols[4] + TableCoords[5];

    for i := 0 to 9999 do
    begin
      y := y - rowHeight;

      AddPageIfNecessary;
      page.SetFont(fontText, 10);

      page.DrawRect(tableCoords[1], y , tableCols[1], rowHeight, 0.2, false, true);
      page.WriteText(tableCoords[1] + 2, y + 3 , 'COL_1');

      page.DrawRect(tableCoords[2], y , tableCols[1], rowHeight, 0.2, false, true);
      page.WriteText(tableCoords[2] + 2, y + 3 , 'COL_2');

      page.DrawRect(tableCoords[3], y , tableCols[1], rowHeight, 0.2, false, true);
      page.WriteText(tableCoords[3] + 2, y + 3 , 'COL_3');

      tmp := FormatFloat('#,##0.00', 333.554);
      page.DrawRect(tableCoords[4], y , tableCols[4], rowHeight, 0.2, false, true);
      page.WriteText(EstimatePos(tableCoords[5], tmp), y + 3 , tmp);
    end;


    y := y - 16;
    AddPageIfNecessary;
    page.SetFont(fontText, 14);
    page.WriteText(x, y, 'END of the document');

    WriteFooter(true);

    fs := TFileStream.Create(aFileName, fmCreate);
    try
      doc.SaveToStream(fs);
    finally
      fs.Free;
    end;
  finally
    doc.Free;
  end;
end;

Titolo: Re:fcl-pdf
Inserito da: SB - Marzo 31, 2019, 09:21:48 am
Grazie!
Volevo provare a portare in FP un programma che avevo fatto in Delphi con QuickReport.
C'è da stampare un questionario con bande ad altezza variabile.
Vorrei la flessibilità di stampare quello che voglio dove voglio, e qualche calcolo sulle posizioni non mi spaventa.

Mi preme non dover dipendere da componenti estranei in modo da realizzare qualcosa di multipiattaforma.
E' una gioia scrivere un programma con Lazarus Linux, compilare lo stesso programma con Lazarus Windows lanciato tramite Wine e vedere che tutto funziona anche su Windows, con nessuno o comunque minimi ritocchi...