* * * *
13 Visitatori, 0 Utenti

Introduzione
In questo breve articolo andremo a vedere come realizzare un dialog che ci permetta di connetterci ad un database.
Prima di iniziare va ricordato che nella wiki ufficiale di lazarus esiste già un esempio simile (al quale mi sono ispirato), la pagina è in: http://wiki.freepascal.org/SQLdb_Tutorial3.
Il codice cui la pagina wiki fa riferimento lo trovate in: [path installazione lazarus]/examples/database/sqldbtutorial3/.

In questo caso verrà realizzato un dialog un po' più semplice, da usare immediatamente e che non salva le sue impostazioni.
E' stato utilizzato il componente TSqlConnector che permette di collegarsi al database desiderato (a patto di avere il client installato) semplicemente specificandone il tipo, qualcosa di simile a quello che fa ZeosLib.


Il Codice
I sorgenti completi con progetto per il test li trovate allegati a questo post: http://www.lazaruspascal.it/index.php?topic=1371.msg8176;topicseen#new.
Segue uno spezzone di codice per spiegare come è stato realizzato.

Codice: [Seleziona]


...

type
  { CallBack connection test}

  TNotifyOnTestConnection = function(const DbType,HostName,DbName,UserName,Password: string): boolean of object;

  { TfmSimpleDbConnectionDialog }

  TfmSimpleDbConnectionDialog = class(TForm)
    BitBtn1: TBitBtn;
    BitBtn2: TBitBtn;
    Button1: TButton;
    edDbName: TEdit;
    edDbType: TComboBox;
    edHostName: TEdit;
    edPassword: TEdit;
    edUserName: TEdit;
    Label1: TLabel;
    Label2: TLabel;
    Label3: TLabel;
    Label4: TLabel;
    Label5: TLabel;
    procedure Button1Click(Sender: TObject);
    procedure FormShow(Sender: TObject);
  private
    { private declarations }
    FOnTestConnection: TNotifyOnTestConnection;
    procedure DoTestConnection;
  public
    { public declarations }
    procedure InitConnectionSettings(const DbType,HostName,DbName,UserName,Password: string);
    procedure AddDbTypes(const ATypes: array of string);
    property OnTestConnection: TNotifyOnTestConnection write FOnTestConnection;
  end;


implementation

...

procedure TfmSimpleDbConnectionDialog.Button1Click(Sender: TObject);
begin
  DoTestConnection
end;


procedure TfmSimpleDbConnectionDialog.FormShow(Sender: TObject);
begin
  Button1.Enabled:=Assigned(FOnTestConnection);
end;

procedure TfmSimpleDbConnectionDialog.DoTestConnection;
begin
  if Assigned(FOnTestConnection) then
     FOnTestConnection(edDbType.Text,edHostName.Text,edDbName.Text,edUserName.Text,edPassword.Text);
end;

procedure TfmSimpleDbConnectionDialog.InitConnectionSettings(const DbType,
  HostName, DbName, UserName, Password: string);
var i: integer;
begin
   if DbType <> '' then begin
      i := edDbType.Items.IndexOf(DbType);
      if i < 0 then begin
         AddDbTypes([DbType]);
          i := edDbType.Items.IndexOf(DbType);
      end;
      edDbType.ItemIndex := i;
   end else
      if edDbType.Items.Count > 0 then
         edDbType.ItemIndex := 0;

   edDbName.Text := DbName;
   edHostName.Text := HostName;
   edUserName.Text := UserName;
   edPassword.Text := Password;
end;

procedure TfmSimpleDbConnectionDialog.AddDbTypes(const ATypes: array of string);
var s: string;
begin
   edDbType.Items.Clear;
   for s in ATypes do
      edDbType.Items.Add(s);
end;

end.


Come vedete il dialog è formato da:
  • un combobox per specificare il tipo di connessione
  • una serie di edit dove indicare i parametri di connessione
  • un bottone che richiama la procedura di test (che deve essere dichiarata dal chiamante)
  • il bottone annulla
  • il bottone conferma


Per richiamare questo dialog, è stato utilizzato questo codice:

Codice: [Seleziona]

unit Unit1;

{$mode objfpc}{$H+}

interface

uses
   ...
   sqldb,   // unit contenente TSqlConnector
   ...

type

  { TForm1 }

  TForm1 = class(TForm)
    Button1: TButton;
    SQLConnector1: TSQLConnector;
    procedure Button1Click(Sender: TObject);
  private
    { private declarations }
    function TestConnection(const DbType,HostName,DbName,UserName,Password: string): boolean;
  public
    { public declarations }
    function ConfiguraConnessione: boolean;
  end;

var
  Form1: TForm1;

implementation

{$R *.lfm}

uses uSimpleDbConnectionDialog,
     IBConnection,     // obbligatorio per connettersi a firebird
     sqlite3conn,      // obbligatorio per connettersi a sqllite
     oracleconnection  // obbligatorio per connettersi a oracle
     ;

{ TForm1 }

procedure TForm1.Button1Click(Sender: TObject);
begin
   if ConfiguraConnessione then
      ShowMessage('Connessione OK')
   else
     ShowMessage('Connessione non riuscita');
end;

function TForm1.TestConnection(const DbType, HostName, DbName, UserName,
  Password: string): boolean;
begin
  SQLConnector1.Close;
  SQLConnector1.ConnectorType := DbType;
  SQLConnector1.HostName := HostName;
  SQLConnector1.DatabaseName := DbName;
  SQLConnector1.UserName := UserName;
  SQLConnector1.Password := Password;
  result := FALSE;
  try
     SQLConnector1.Open;
     ShowMessage('Test connessione riuscito!');
     SQLConnector1.Close(TRUE);
     result := TRUE;
  except
     on e: exception do begin
        MessageDlg(Application.Title,
                  'Errore durante la connessione!' + LineEnding + LineEnding +
                  e.Message, mtError, [mbOk], 0);
     end;
  end;
end;

function TForm1.ConfiguraConnessione: boolean;
begin
  result := FALSE;
  with TfmSimpleDbConnectionDialog.Create(Application) do
     try
        // il test della connessione lo fa il chiamante
        // assegnamo quindi il puntatore alla procedura di CallBack
        OnTestConnection := @TestConnection;

        // tipi di connessioni ammesse dal dialog
        AddDbTypes(['Firebird','SqlLite','Oracle']);

        // inizializzazione dei campi di edit
        // ad esempio si possono estrarre i valori da un file do configurazione
        InitConnectionSettings('Firebird',
                               'digitare IP o hostname',
                               'nome del database',
                               'nome utente',
                               '');

        if ShowModal = mrOk then begin
           SqlConnector1.ConnectorType := edDbType.Items[edDbType.ItemIndex];
           SqlConnector1.HostName := edHostName.Text;
           SqlConnector1.DatabaseName := edDbName.Text;
           SqlConnector1.UserName := edUserName.Text;
           SqlConnector1.Password := edPassword.Text;
           try
              SqlConnector1.Open;
              result := TRUE;
           except
              on e: exception do begin
                 MessageDlg(Application.Title,
                           'Errore durante la connessione!' + LineEnding + LineEnding +
                           e.Message, mtError, [mbOk], 0);
              end;
           end;

        end;
     finally
       Free;
     end;

end;

end.


Il codice è abbastanza semplice, autoesplicativo e commentato.
Va comunque spiegato il motivo della procedura di callback per il test della connessione.

Questa procedura
Codice: [Seleziona]
function TestConnection(const DbType,HostName,DbName,UserName,Password: string): boolean;

è dichiarata conformemente a quanto specificato da: TNotifyOnTestConnection.
Infatti prima di istanziare la dialog viene eseguito il seguente codice:
Codice: [Seleziona]

        // il test della connessione lo fa il chiamante
        // assegnamo quindi il puntatore alla procedura di CallBack
        OnTestConnection := @TestConnection;


In questo modo è il chiamante che si preoccupa di fare il test e non il dialog. Il motivo è presto detto: se invece di collegarsi con un database tramite SqlDb volete farlo con ZeosLib o con qualche altra libreria, siete liberissimi di farlo. Se volete aggiungere il tipo connessione odbc, siete liberi di farlo.
All'interno della vostra applicazione dovrete poi gestire i casi che avrete personalizzato.
In questo modo il dialog rimane semplice ed utilizzabile con qualsiasi tipo di componente.



Share on Twitter! Digg this story! Del.icio.us Share on Facebook! Technorati Reddit StumbleUpon

Articles in « How to »

Comments *

Commenting option has been turned off for this article.

Recenti

How To

Trascinare un file nel programma da xinyiman
DB concetti fondamentali e ZeosLib da xinyiman
Recuperare codice HTML da pagina web da xinyiman
Mandare mail con Lazarus da xinyiman
Stabilire il sistema operativo da xinyiman
Esempio lista in pascal da xinyiman
File INI da xinyiman
Codice di attivazione da xinyiman
Realizzare programmi multilingua da xinyiman
Lavorare con le directory da xinyiman
Utilizzare Unità esterne da Loryea
TTreeView da xinyiman
TTreeview e Menu da xinyiman
Generare controlli RUN-TIME da xinyiman
LazReport, PDF ed immagini da xinyiman
Intercettare tasti premuti da xinyiman
Ampliare Lazarus da xinyiman
Lazarus e la crittografia da xinyiman
System Tray con Lazarus da xinyiman
UIB: Unified Interbase da Microges2000
Il file: questo sconosciuto da Microges2000
Conferma di chiusura di un applicazione da xinyiman
Liste e puntatori da Microges2000
Overload di funzioni da Microges2000
Funzioni a parametri variabili da Microges2000
Proprietà da Microges2000
Conversione numerica da Microges2000
TImage su Form e Panel da Maverich
Indy gestiore server FTP lato Client da Maverich
PopUpMenu sotto Pulsante (TSpeedButton) da Maverich
Direttiva $macro da Microges2000
Toolbar da xinyiman
Evidenziare voci TreeView da Maverich
Visualizzare un file Html esterno da Maverich
StatusBar - aggirare l'errore variabile duplicata da Maverich
Da DataSource a Excel da xinyiman
Le permutazioni da xinyiman
Brute force da xinyiman
Indy 10 - Invio email con allegati da Maverich
La gestione degli errori in Lazarus da xinyiman
Pascal Script da xinyiman
Linux + Zeos + Firebird da xinyiman
Dataset virtuale da xinyiman
Overload di operatori da Microges2000
Lavorare con file in formato JSON con Lazarus da nomorelogic
Zeos ... dietro le quinte (prima parte) da Stilgar
Disporre le finestre in un blocco unico (come Delphi) da Maverich
Aspetto retrò (Cmd Line) da xinyiman
Come interfacciare periferica twain da Narciso
Ubuntu - aggiornare free pascal e lazarus da xinyiman
fpcup: installazioni parallele di lazarus e fpc da nomorelogic
Free Pascal e Lazarus sul Raspberry Pi da nomorelogic
Cifratura: breve guida all'uso dell'algoritmo BlowFish con lazarus e free pascal. da nomorelogic
Creare un server multithread da xinyiman
guida all'installazione di fpc trunk da subversion in linux gentoo da nomorelogic
Indice da nomorelogic
DB concetti fondamentali e connessioni standard da xinyiman
Advanced Record Syntax da nomorelogic
DB concetti fondamentali e DBGrid da xinyiman
DB concetti fondamentali e TDBEdit, TDBMemo e TDBText da xinyiman
Advanced Record Syntax: un esempio pratico da nomorelogic
Superclasse form base per programmi gestionali (e non) da nomorelogic
Superclasse form base per programmi gestionali (e non) #2 - log, exception call stack, application toolbox da nomorelogic
Superclasse form base per programmi gestionali (e non) #3 - traduzione delle form da nomorelogic
Superclasse form base per programmi gestionali (e non) #4 - wait animation da nomorelogic
Un dialog per la connessione al database:TfmSimpleDbConnectionDialog da nomorelogic
Installare lazarus su mac osx sierra da xinyiman
Utenti
Stats
  • Post in totale: 10331
  • Topic in totale: 1310
  • Online Today: 25
  • Online Ever: 74
  • (Luglio 09, 2012, 11:05:53 am)
Utenti Online
Users: 0
Guests: 13
Total: 13

Disclaimer:

Questo blog non rappresenta una testata giornalistica poiché viene aggiornato senza alcuna periodicità. Non può pertanto considerarsi un prodotto editoriale ai sensi della legge n. 62/2001.